Mailing Lists: Apple Mailing Lists
Image of Mac OS face in stamp
 
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: Office 2004 updates via ARD

Title: Re: Office 2004 updates via ARD
On 2/8/07 16:23, "John C. Welch" <email@hidden> wrote:

Hi all,

I was curious on how you guys handle pushing out Office 2004 updates (aka 11.3.3) to all of your machines via ARD?

I install it on my laptop, (also the ARD administrator system), read the readme to find out which files were updated, then just push those files out to the various clients. When I get a chance, I’m going to set this up as a folder action, so all I have to do is copy the file to a folder in my Dock and AppleScript does the rest. Dead simple really.

Okay, so I did a quick sample script for this. You can either copy it from here and save it in Script Editor, Script Debugger, Smile, etc., or download it from <http://hompage.mac.com/jcwelch/ardmsofficeupdatescript.zip>. You should save it into /Library/Scripts/Folder Action Scripts/, create a folder to attach the script to, then attach the script to the folder using the Folder Actions Setup application in /Applications/AppleScript/.

One note: you HAVE to watch the location (this is where it is going on the CLIENT).  Because Office updates can go in a few places, and because to run this script, you change the relative location of the files being updated, you can’t really hardcode the destination. Since this is more of a sample/starting point script, I punted and use a display dialog. Since I get the quoted form of what is entered, I don’t need to remember to escape spaces, etc. You can get a lot more clever with this, including parsing out the readmes, etc., but that’s up to your needs. If there were office updates coming out more often, I’d care more about that aspect.

on adding folder items to theFolder after receiving theAddedItems
   -- this repeat loop is something I do, because if a file takes more than a few seconds to copy/move into the file,
    -- the folder action will start running BEFORE the file is completely there. I dislike that.
    repeat with x in theAddedItems
       set theFileInfo to info for x --get info for the downloading file(s)
        set theBaseSize to size of theFileInfo --get initial size
        delay 3 --wait 3 seconds
        set theFileInfo to info for x --get info again
        set theCompareSize to size of theFileInfo --get a newer size
        repeat while theCompareSize ≠ theBaseSize --if they don't equal, loop until they do
            set theBaseSize to theCompareSize --new base size
            delay 3 --wait three seconds
            set theFileInfo to info for x --get info
            set theCompareSize to size of theFileInfo --get a newer size
        end repeat --once the sizes match, the download is done
    end repeat
    try
        set theDestinationRecord to display dialog ¬
            "Enter the unix-style path to the Office folder you want the file(s) copied to" default answer "/Applications/Microsoft Office 2004/"
        --get the path to the file's destination.
        set theDestination to text returned of theDestinationRecord as text --grab the text
        set theDestinationPath to quoted form of theDestination --get the quoted form of the text
    end try
    tell application "Remote Desktop"
        --set thePackageInstall to make new install package task with properties {delegating to task server:false, encrypting:true, packages:theAddedItems, stopping on error:false}
        set theApplicationCopy to make new copy items task with properties ¬
            {conflict resolution:replace, copy items:theAddedItems, encrypting:true, location:specific folder, destination path:theDestinationPath, ownership:destination folder owner, stopping on error:false}
        set theTaskResult to execute theApplicationCopy on computer list "Office Installs"
        display dialog (status of theTaskResult) giving up after 60
   end tell
end adding folder items to

--
John C. Welch         Writer/Analyst
Bynkii.com              Mac and other opinions
email@hidden
 
 _______________________________________________
Do not post admin requests to the list. They will be ignored.
Remote-desktop mailing list      (email@hidden)
Help/Unsubscribe/Update your Subscription:
http://lists.apple.com/mailman/options/remote-desktop/email@hidden

This email sent to email@hidden
References: 
 >Re: Office 2004 updates via ARD (From: "John C. Welch" <email@hidden>)



Visit the Apple Store online or at retail locations.
1-800-MY-APPLE

Contact Apple | Terms of Use | Privacy Policy

Copyright © 2007 Apple Inc. All rights reserved.