Re: QT Batch Processing
Re: QT Batch Processing
- Subject: Re: QT Batch Processing
- From: Brennan Young <email@hidden>
- Date: Fri, 08 Jun 2001 22:47:09 +0200
- Organization: Magic Lantern
john Dawson <email@hidden> wrote
>
I am trying to acsertain if it is possible to use Applescript and QT
>
player(or another app.) to batch process QT movies?
Sure. The other apps would be moviescript (anyone using that?) or hypercard, but
Quicktime Player is the most spangly and modern. (Not to mention the cheapest).
>
We would like to automate a process that involves "Topping" & "Tailing"
>
.mov's with other .mov's.
>
>
ie: copying an intro movie and pasting it at the start of a target movie,
>
then copying another outro movie to be pasted at the end of the same target
>
movie. The target movie should then be saved as "self contained." The script
>
will repeat the process for all of the .mov's situated in the same folder.
My culinary experience would tell me that topping and tailing would involve
removing the beginning and the end, rather than adding, but OK.
>
Any ideas as to how to achieve this or thoughts as to whether its possible
>
would be highly appreciated.
How's this:
set introFile to (choose file with prompt "Choose intro file")
set outroFile to (choose file with prompt "Choose outro file")
set theMovieFolder to (choose folder with prompt "Choose folder of movies")
tell application "QuickTime Player"
activate
set intro to (open introFile) as reference
set outro to (open outroFile) as reference
end tell
set theMoviesPath to theMovieFolder as string
set theMovieNames to (list folder theMovieFolder)
repeat with m in theMovieNames
set thisMovie to (theMoviesPath & m)
tell application "QuickTime Player"
set underTheKnife to (open thisMovie) as reference
tell intro
select all
copy
end tell
tell underTheKnife
set current time to 0
paste
end tell
tell outro
select all
copy
end tell
tell underTheKnife
set d to duration
set current time to d
paste
set newName to ("_" & m)
save in (theMoviesPath & newName) as self contained
end tell
close movie newName
end tell
end repeat
This will save the new movies in the same folder as the old ones, but with an
underscore at the beginning of the filename.
--
_____________
Brennan