on test_file_exists(targetFilePath)
try
(POSIX file targetFilePath) as alias ## Generates an error if no file exists ##
on error errMsg number errNum
set errorText to "Script Failed in test_file_exists handler..." & linefeed & linefeed ¬
& errMsg & linefeed & linefeed & "Error Number: " & errNum
error errorText
end try
end test_file_exists
# ======================================================================
on read_config_file(targetFilePath)
try
set fileData to read targetFilePath
return fileData
on error errMsg number errNum
set errorText to "Script Failed in read_config_file handler..." & linefeed & linefeed ¬
& errMsg & linefeed & linefeed & "Error Number: " & errNum
error errorText
end try
end read_config_file
# ======================================================================
on write_to_config_file(textToWrite, targetFilePath)
try
set resultNumber to open for access targetFilePath ¬
with write permission
set eof of resultNumber to 0
write textToWrite to resultNumber
close access resultNumber
on error errMsg number errNum
try
close access resultNumber
on error errMsg number errNum
set errorText to "Script Failed in write_to_config_file handler..." & linefeed & linefeed ¬
& errMsg & linefeed & linefeed & "Error Number: " & errNum
error errorText
end try
end try
end write_to_config_file
# ======================================================================
property targetFilePath : POSIX path of (path to application support folder from user domain) & ¬
".yourConfigFileName"
property LF : linefeed
# ======================================================================
# Write the file first to make sure it gets created.
# Overwrites if file already exists.
try
set textToWrite to "Don't you know that none are blind
To the lie, and you think I don't find what you hide?"
set writeResult to write_to_config_file(textToWrite, targetFilePath) of me
# Do something else.
on error errMsg number errNum
beep
tell me to display dialog "Error: " & errMsg
end try
# Test for existence of the '.yourConfigFileName' file.
try
test_file_exists(targetFilePath) of me ## stops executing here if no file ##
## If file exists then code here gets executed ##
on error errMsg number errNum
beep
tell me to display dialog "Error: " & errMsg
end try
# Read the file.
try
set configData to read_config_file(targetFilePath) of me
on error errMsg number errNum
beep
tell me to display dialog "Error: " & errMsg
end try
tell application "TextEdit"
activate
open targetFilePath
end tell