There are several errors in your scripts so it can't do what it's supposed to achieve.
For instance, the Finder can't create a folder in a string as you urge it to do.
I assume that the folder to which the script is attached is the folder which you name ptdpp.
I edited the script accordingly.
I disabled the code specific to Photoshop because I don't own it.
Here is my edited version.
on adding folder items to this_folder after receiving PhotoshopFiles
set ptd to path to desktop as text
--set ptdpp to ptd & "Photoshop Processing" as text
set ptdpp to this_folder as text
set ptdpif to ptd & "Processed Images Folder" as text
set ptdpsf to ptd & "Processed Stored Folder" as text
set fileToLog to (ptdpif) & ":Photoshop_Batch_Errors_Log.txt" as text
tell application "Finder"
set PhotoshopFiles to files of folder ptdpp as alias list
if not (exists folder ptdpsf) then
make new folder at folder ptd with properties {name:"Processed Stored Folder"}
end if
if not (exists folder ptdpif) then
make new folder at folder ptd with properties {name:"Processed Images Folder"}
end if
if not (exists file fileToLog) then
make new file at folder ptdpif with properties {name:"Photoshop_Batch_Errors_Log.txt"}
end if
end tell
say (count of PhotoshopFiles)
(*
tell application "Adobe Photoshop CS5"
activate
set display dialogs to never
batch "Wood Frame - 50 pixel" from "Default Actions" from files PhotoshopFiles with options {destination:folder, destination folder:alias ptdpif, error file:alias fileToLog, macintosh compatible:true, file naming:{document name mixed, extension lower}, suppress open:true, override save:true}
end tell
*)
tell application "Finder"
move PhotoshopFiles to folder ptdpsf
end tell
end adding folder items to