The most straightforward way to write plain text to be sure.
------------------------------------------------------------------------------------------------
do shell script "open ~/Downloads"
set filePath1 to do shell script "echo ~/Downloads/Posix_Path.txt"
set filePath2 to POSIX file (do shell script "echo ~/Downloads/Posix_File_Path.txt")
set filePath3 to ((path to downloads folder as text) & "HFS_Path.txt")
set fileList to {filePath1, filePath2, filePath3}
repeat with ndx in fileList
try
set fRef to open for access ndx with write permission
write "This is sample text" to fRef
close access fRef
on error
try
close access fRef
end try
end try
end repeat
# It will also accept an alias if the file already exists.
------------------------------------------------------------------------------------------------
My general purpose write handlers.
------------------------------------------------------------------------------------------------
--» Write_To_File()
------------------------------------------------------------------------------------------------
-- Purpose: Write to a file as a specific data-type.
-- Modified: 2012-10-26 : 20:00
------------------------------------------------------------------------------------------------
on Write_To_File(srcData, targetFile, startPosition, dataType)
try
set fileRef to open for access targetFile with write permission
if startPosition = 0 then
set eof of fileRef to 0
else if startPosition = eof then
set startPosition to get eof of fileRef
end if
write srcData to fileRef as dataType starting at startPosition
close access fileRef
on error errMsg number errNum
try
close access fileRef
end try
display dialog "Error: " & errMsg & return & "Error Number: " & errNum
end try
end Write_To_File
------------------------------------------------------------------------------------------------
--» write_to_file_overwriting()
------------------------------------------------------------------------------------------------
-- Purpose: Write text to a file and overwrite any content.
-- Modified: 2012-10-26 : 20:00
------------------------------------------------------------------------------------------------
on write_to_file_overwriting(srcText, targetFile)
try
set fileRef to open for access targetFile with write permission
set eof of fileRef to 0
write srcText to fileRef
close access fileRef
on error errMsg number errNum
try
close access fileRef
on error errMsg number errNum
beep
display dialog "Error: " & errMsg & return & "Error Number: " & errNum
end try
end try
end write_to_file_overwriting
------------------------------------------------------------------------------------------------
set filePath1 to do shell script "echo ~/Downloads/Text_Overwriting.txt"
set filePath2 to POSIX file (do shell script "echo ~/Downloads/Write_as_List.txt")
set filePath3 to ((path to downloads folder as text) & "Write_Text_Appending.txt")
write_to_file_overwriting("Write to file with overwriting", filePath1)
Write_To_File({"one", "two", "three"}, filePath2, 0, list)
repeat 3 times
Write_To_File("Write to file with appending." & linefeed & linefeed, filePath3, eof, text)
end repeat
# Writing as list allows you to read as list.
------------------------------------------------------------------------------------------------
------------------------------------------------------------------------------------------------