• Open Menu Close Menu
  • Apple
  • Shopping Bag
  • Apple
  • Mac
  • iPad
  • iPhone
  • Watch
  • TV
  • Music
  • Support
  • Search apple.com
  • Shopping Bag

Lists

Open Menu Close Menu
  • Terms and Conditions
  • Lists hosted on this site
  • Email the Postmaster
  • Tips for posting to public mailing lists
Re: Determining accessibility of Applescript App?
[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Re: Determining accessibility of Applescript App?


  • Subject: Re: Determining accessibility of Applescript App?
  • From: Bill Cheeseman <email@hidden>
  • Date: Tue, 30 Aug 2016 04:28:59 -0400


On Aug 30, 2016, at 3:00 AM, Brian Christmas <email@hidden> wrote:

Anyone know of  a way of determining an Apps accessibility without this try trap. please?

Here is the all-purpose script handler that I make available in UI Browser <pfiddlesoft.com/uibrowser>:

on enabledGUIScripting(flag)
considering numeric strings
set MountainLionOrOlder to system version of (system info) < "10.9"
end considering
if MountainLionOrOlder then


-- In OS X 10.8 Mountain Lion and older, enable GUI Scripting globally by calling this handler and passing 'true' in the flag parameter before your script executes any GUI Scripting commands, or pass 'false' to disable GUI Scripting. Authentication is required only if the value of the 'UI elements enabled' property will be changed. Returns the final setting of 'UI elements enabled' even if unchanged.


tell application "System Events"
activate -- brings System Events authentication dialog to front
set UI elements enabled to flag
return UI elements enabled
end tell
else


-- In OS X 10.9 Mavericks and newer, global access is no longer available and GUI Scripting can only be enabled manually on a per-application basis. Pass true to present an alert with a button to open System Preferences and telling the user to select the current application (the application running the script) in the Accessibility list in the Security & Privacy preference's Privacy pane. Authentication is required to unlock the preference. Returns the current setting of 'UI elements enabled' asynchronously, without waiting for System Preferences to open, and tells the user to run the script again.


tell application "System Events" to set GUIScriptingEnabled to UI elements enabled -- read-only in OS X 10.9 Mavericks and newer
if flag is true then
if not GUIScriptingEnabled then
activate
set scriptRunner to name of current application
display alert "GUI Scripting is not enabled for " & scriptRunner & "." message "Open System Preferences, unlock the Security & Privacy preference, select " & scriptRunner & " in the Privacy Pane's Accessibility list, and then run this script again." buttons {"Open System Preferences", "Cancel"} default button "Cancel"
if button returned of result is "Open System Preferences" then
tell application "System Preferences"
tell pane id "com.apple.preference.security" to reveal anchor "Privacy_Accessibility"
activate
end tell
end if
end if
end if
return GUIScriptingEnabled
end if
end enabledGUIScripting

 _______________________________________________
Do not post admin requests to the list. They will be ignored.
AppleScript-Users mailing list      (email@hidden)
Help/Unsubscribe/Update your Subscription:
Archives: http://lists.apple.com/archives/applescript-users

This email sent to email@hidden

References: 
 >Determining accessibility of Applescript App? (From: Brian Christmas <email@hidden>)

  • Prev by Date: Re: "where its" vs "whose"
  • Next by Date: Fwd: Determining accessibility of Applescript App?
  • Previous by thread: Determining accessibility of Applescript App?
  • Next by thread: Fwd: Determining accessibility of Applescript App?
  • Index(es):
    • Date
    • Thread