Apple

Le 25 mars 2017 à 00:33, Christopher Stone <email@hidden> a écrit :

On Mar 24, 2017, at 11:21, Jeremy Roussak <email@hidden> wrote:
Thanks. That does it.

Hey Jeremy,

Rule-of-the-thumb – never depend upon what Apple's idea of words is.

Doing so will always bite you somewhere down the line.

Always use AppleScript's text item delimiters, which you have explicit control over.

Or use a method that gives you similar explicit control.

An example using the Satimage.osax:

------------------------------------------------------------------------------

set theString to "eric v smith & jones"
set stringComponentList to find text "\\S+" in theString with regexp, all occurrences and string result

--> {"eric", "v", "smith", "&", "jones"}

------------------------------------------------------------------------------

AppleScriptObjC works quite well for this as well and returns the same result. (This is equivalent to using AppleScript's text item delimiters.)

------------------------------------------------------------------------------

use framework "Foundation"
use scripting additions

set theString to "eric v smith & jones"

set stringComponentList to my splitstring:theString withString:" "

------------------------------------------------------------------------------
--» HANDLERS
------------------------------------------------------------------------------
on splitstring:someText withString:mySeparator -- borrowed from Yvan Koenig who borrowed it from Shane STANLEY
set theString to current application's NSString's stringWithString:someText
set theList to theString's componentsSeparatedByString:mySeparator
return theList as list
end splitstring:withString:
------------------------------------------------------------------------------

Using a regular _expression_ with AppleScriptObjC:

------------------------------------------------------------------------------

use framework "Foundation"
use scripting additions

set theString to "eric v smith & jones"

set stringComponentList to my reMatch:"\\S+" inText:theString

------------------------------------------------------------------------------
--» HANDLERS
------------------------------------------------------------------------------
on reMatch:findPattern inText:theText
set theNSString to current application's NSString's stringWithString:theText
set theOptions to ((current application's NSRegularExpressionDotMatchesLineSeparators) as integer) + ((current application's NSRegularExpressionAnchorsMatchLines) as integer)
set theRegEx to current application's NSRegularExpression's regularExpressionWithPattern:findPattern options:theOptions |error|:(missing value)
set theFinds to theRegEx's matchesInString:theNSString options:0 range:{location:0, |length|:theNSString's |length|()}
set theFinds to theFinds as list -- so we can loop through
set theResult to {} -- we will add to this

repeat with i from 1 to count of items of theFinds
set theRange to (item i of theFinds)'s range()
set end of theResult to (theNSString's substringWithRange:theRange) as string
end repeat

return theResult

end reMatch:inText:
------------------------------------------------------------------------------

------------------------------------------------------------------------------
Tags: @AppleScript, @Script, @ASObjC, @ccstone, @RegEx, @Match, @String, @Find
------------------------------------------------------------------------------

--
Best Regards,
Chris

References:
	>Missing ampersand (From: Jeremy Roussak <email@hidden>)
	>Re: Missing ampersand (From: Yvan KOENIG <email@hidden>)
	>Re: Missing ampersand (From: Jeremy Roussak <email@hidden>)
	>Re: Missing ampersand (From: Christopher Stone <email@hidden>)