Unfortunately it doesn't look like this method can be made to work with Google Chrome.
You can get to the first tab whose url is the one you're looking for.
But you can't get to the window using that tab as a reference — not with a bare whose clause anyway.
Okay, I figured out how to do it with the Tab-ID.
------------------------------------------------------------------------------
# Auth: Christopher Stone { Building on work of Axel Luttgens }
# dCre: 2017/05/21 19:14
# dMod: 2017/05/21 19:48
# Appl: Google Chrome
# Task: Bring a tab containing a given URL to the front.
# Libs: None
# Osax: None
# Tags: @Applescript, @Script, @Google_Chrome, @Bring, @Window, @Tab, @Containing, @URL, @Frontmost
------------------------------------------------------------------------------
tell application "Google Chrome"
try
repeat with tabOfInterest in (tabs of windows whose URL contains searchStr)
set tabOfInterest to contents of tabOfInterest
exit repeat
end repeat
set tabID to id of tabOfInterest
set theWin to item 1 of (windows where id of tabs contains tabID)
tell theWin
set index to 1
raiseWindowOne() of me
set tabIDList to id of tabs
repeat with i from 1 to length of tabIDList
if item i of tabIDList = tabID then
set active tab index to i
end if
end repeat
end tell
on error
if window 1 exists then
tell window 1
make new tab at end with properties {URL:searchStr}
end tell
else
make new window
tell active tab of front window to set its URL to searchStr
end if
end try
end tell
------------------------------------------------------------------------------
--» HANDLERS
------------------------------------------------------------------------------
on raiseWindowOne()
tell application "System Events"
tell (first application process whose frontmost is true)
tell window 1 to perform action "AXRaise"
end tell
end tell
end raiseWindowOne
------------------------------------------------------------------------------